kdb+ Order Book Visualization

Adding a kdb+ Streaming Server
Populating Data
Adding our Trade Blotter
Customizing Table Appearance

Download Pulse

Warning: DepthMap is currently experimental and may consume heavy CPU/RAM resources.

Add kdb+ Server Connection

To add a streaing kdb+ connection:

Goto Connections page.
Click Add Connection.
Make sure to select Kdb_Streaming.
Fill in your details and click add.

Populating the Tables

Copy and Paste the below code into the SQL Editor and press "Send Query":

// Example of generating order book in kdb+

walk:{ [seed;n]
	 r:{{ abs ((1664525*x)+1013904223) mod 4294967296}\[y-1;x]};
	 prds (500+((r[seed;n]) mod 11)-5)%500.0};


mid:50.+rand[50.0];
j:0.5; // price jump between levels

// Generating trades and quotes in order book format for Pulse
// https://timestored.com/pulse/help/marketdata-format    
genOrderBook:{[] 
    c:1+rand[3];
    m:$[mid<50;60;mid];
    aa:walk[rand 5000;c]*m;
    mid::last aa;
    t:([] date:c#.z.t; symbol:c#`f; a0:aa; as0:40+c?20);
    t:update b0:a0-1,bs0:40+c?20 from t;
    t:update a1:a0+j, as1:30+c?9, b1:b0-j, bs1:30+c?9 from t;
    t:update a2:a1+j, as2:20+c?9, b2:b1-j, bs2:20+c?9 from t;
    t:update a3:a2+j, as3:10+c?9, b3:b2-j, bs3:10+c?9 from t;
    t:update a4:a3+j*rand[3]+1, as4:5+c?9, b4:b3-j*rand[3]+1, bs4:5+c?9 from t;
    t:update a5:a4+j*rand[3]+1, as5:3+c?9, b5:b4-j*rand[3]+1, bs5:3+c?9 from t;
    t:update a6:a5+j*rand[3]+1, as6:c?9,   b6:b5-j*rand[3]+1, bs6:c?9 from t;
    t:update a7:a6+j*rand[3]+1, as7:c?5,   b7:b6-j*rand[3]+1, bs7:c?5 from t;
    t};
 
genTrades:{[]
    c:1+rand[3];
    t:([] tradeDate:c#.z.t; symbol:c#`f; price:walk[rand[5000];c]*mid+j*rand[16]-8; quantity:c?20);
    t};

orderbook:genOrderBook[];
trades:genTrades[];
 
// Allows subscriptions but only supports 1 client
clienth:();
.u.sub:{[tblName;symList] clienth::clienth,.z.w; tName::tblName;};

pubToClient:{
    newQuotes:genOrderBook[];
    insert[`orderbook;newQuotes];
    if[count hs:clienth inter key .z.W; 
        upQuotes:(`.u.upd;`q;update tName:@[get;`tName;`noTname] from newQuotes); 
        {neg[x] y}[;upQuotes] each hs;
        if[10<rand 12; // Only publish trades infrequently.
            newTrades:genTrades[];
            insert[`trades;newTrades];
            {neg[x] y}[;(`.u.upd;`t;newTrades)] each hs;]];
    };

main:{
    .z.ts:{pubToClient[]; orderbook::-5000 sublist orderbook; trades::-5000 sublist trades; };
    system "t 200";    
    };

main[];

Add and Edit Application

On the applications listing page, click add
Click on the newly created application to go into it. Either click on edit or toggle design mode once in the application.